6a329eb853
Capture TransferList address from register x3 Refer to section 3 of the FW Handoff Specification https://firmwarehandoff.github.io/firmware_handoff The TransferList header is present at the base address captured by this variable. For platforms with no TransferList support, boot continues without any errors. Signed-off-by: Prachotan Bathi <prachotan.bathi@arm.com>
75 lines
2.4 KiB
ArmAsm
75 lines
2.4 KiB
ArmAsm
//
|
|
// Copyright (c) 2011-2014, ARM Limited. All rights reserved.
|
|
//
|
|
// SPDX-License-Identifier: BSD-2-Clause-Patent
|
|
//
|
|
//
|
|
|
|
#include <AsmMacroLib.h>
|
|
|
|
ASM_FUNC(_ModuleEntryPoint)
|
|
// Check if register assignment at handoff matches spec
|
|
MOV64 (x4, 0x14a0fb10b)
|
|
// Check if x1 holds TransferList signature
|
|
cmp x1, x4
|
|
b.ne _SkipTransferList
|
|
|
|
// Skip TransferList init if x2 is not equal to 0
|
|
cbnz x2, _SkipTransferList
|
|
|
|
// Set the TransferList Base Address from register x3
|
|
mov x10, x3
|
|
|
|
_SkipTransferList:
|
|
// Do early platform specific actions
|
|
bl ASM_PFX(ArmPlatformPeiBootAction)
|
|
|
|
// NOTE: We could be booting from EL3, EL2 or EL1. Need to correctly detect
|
|
// and configure the system accordingly. EL2 is default if possible.
|
|
// If we started in EL3 we need to switch and run at EL2.
|
|
// If we are running at EL2 stay in EL2
|
|
// If we are starting at EL1 stay in EL1.
|
|
|
|
// If started at EL3 Sec is run and switches to EL2 before jumping to PEI.
|
|
// If started at EL1 or EL2 Sec jumps directly to PEI without making any
|
|
// changes.
|
|
|
|
// Which EL are we running at? Every EL needs some level of setup...
|
|
// We should not run this code in EL3
|
|
EL1_OR_EL2(x0)
|
|
1:bl ASM_PFX(SetupExceptionLevel1)
|
|
b ASM_PFX(MainEntryPoint)
|
|
2:bl ASM_PFX(SetupExceptionLevel2)
|
|
b ASM_PFX(MainEntryPoint)
|
|
|
|
ASM_PFX(MainEntryPoint):
|
|
// Get the top of the primary stacks (and the base of the secondary stacks)
|
|
MOV64 (x1, FixedPcdGet64(PcdCPUCoresStackBase) + FixedPcdGet32(PcdCPUCorePrimaryStackSize))
|
|
|
|
// Set up the stack pointer
|
|
mov sp, x1
|
|
|
|
// Apply the init value to the entire stack
|
|
MOV64 (x8, FixedPcdGet64 (PcdCPUCoresStackBase))
|
|
MOV64 (x9, FixedPcdGet32 (PcdInitValueInTempStack) |\
|
|
FixedPcdGet32 (PcdInitValueInTempStack) << 32)
|
|
0:stp x9, x9, [x8], #16
|
|
cmp x8, x1
|
|
b.lt 0b
|
|
|
|
// The PEI Core Entry Point has been computed by GenFV and stored in the second entry of the Reset Vector
|
|
MOV64 (x2, FixedPcdGet64(PcdFvBaseAddress))
|
|
ldr x0, [x2, #8]
|
|
// Pass the TransferList Base Address
|
|
mov x1, x10
|
|
// Move sec startup address into a data register
|
|
// Ensure we're jumping to FV version of the code (not boot remapped alias)
|
|
ldr x3, =ASM_PFX(CEntryPoint)
|
|
|
|
// Set the frame pointer to NULL so any backtraces terminate here
|
|
mov x29, xzr
|
|
|
|
// Jump to PrePeiCore C code
|
|
// x0 = pei_core_address
|
|
blr x3
|